home *** CD-ROM | disk | FTP | other *** search
/ SGI Developer Toolbox 6.1 / SGI Developer Toolbox 6.1 - Disc 4.iso / lib / mathlib / libblas / src_original / ztpsv.f < prev    next >
Encoding:
Text File  |  1994-08-02  |  11.1 KB  |  345 lines
  1. *
  2. ************************************************************************
  3. *
  4.       SUBROUTINE ZTPSV ( UPLO, TRANS, DIAG, N, AP, X, INCX )
  5. *     .. Scalar Arguments ..
  6.       INTEGER            INCX, N
  7.       CHARACTER*1        DIAG, TRANS, UPLO
  8. *     .. Array Arguments ..
  9.       COMPLEX*16         AP( * ), X( * )
  10. *     ..
  11. *
  12. *  Purpose
  13. *  =======
  14. *
  15. *  ZTPSV  solves one of the systems of equations
  16. *
  17. *     A*x = b,   or   A'*x = b,   or   conjg( A' )*x = b,
  18. *
  19. *  where b and x are n element vectors and A is an n by n unit, or
  20. *  non-unit, upper or lower triangular matrix, supplied in packed form.
  21. *
  22. *  No test for singularity or near-singularity is included in this
  23. *  routine. Such tests must be performed before calling this routine.
  24. *
  25. *  Parameters
  26. *  ==========
  27. *
  28. *  UPLO   - CHARACTER*1.
  29. *           On entry, UPLO specifies whether the matrix is an upper or
  30. *           lower triangular matrix as follows:
  31. *
  32. *              UPLO = 'U' or 'u'   A is an upper triangular matrix.
  33. *
  34. *              UPLO = 'L' or 'l'   A is a lower triangular matrix.
  35. *
  36. *           Unchanged on exit.
  37. *
  38. *  TRANS  - CHARACTER*1.
  39. *           On entry, TRANS specifies the equations to be solved as
  40. *           follows:
  41. *
  42. *              TRANS = 'N' or 'n'   A*x = b.
  43. *
  44. *              TRANS = 'T' or 't'   A'*x = b.
  45. *
  46. *              TRANS = 'C' or 'c'   conjg( A' )*x = b.
  47. *
  48. *           Unchanged on exit.
  49. *
  50. *  DIAG   - CHARACTER*1.
  51. *           On entry, DIAG specifies whether or not A is unit
  52. *           triangular as follows:
  53. *
  54. *              DIAG = 'U' or 'u'   A is assumed to be unit triangular.
  55. *
  56. *              DIAG = 'N' or 'n'   A is not assumed to be unit
  57. *                                  triangular.
  58. *
  59. *           Unchanged on exit.
  60. *
  61. *  N      - INTEGER.
  62. *           On entry, N specifies the order of the matrix A.
  63. *           N must be at least zero.
  64. *           Unchanged on exit.
  65. *
  66. *  AP     - COMPLEX*16       array of DIMENSION at least
  67. *           ( ( n*( n + 1 ) )/2 ).
  68. *           Before entry with  UPLO = 'U' or 'u', the array AP must
  69. *           contain the upper triangular matrix packed sequentially,
  70. *           column by column, so that AP( 1 ) contains a( 1, 1 ),
  71. *           AP( 2 ) and AP( 3 ) contain a( 1, 2 ) and a( 2, 2 )
  72. *           respectively, and so on.
  73. *           Before entry with UPLO = 'L' or 'l', the array AP must
  74. *           contain the lower triangular matrix packed sequentially,
  75. *           column by column, so that AP( 1 ) contains a( 1, 1 ),
  76. *           AP( 2 ) and AP( 3 ) contain a( 2, 1 ) and a( 3, 1 )
  77. *           respectively, and so on.
  78. *           Note that when  DIAG = 'U' or 'u', the diagonal elements of
  79. *           A are not referenced, but are assumed to be unity.
  80. *           Unchanged on exit.
  81. *
  82. *  X      - COMPLEX*16       array of dimension at least
  83. *           ( 1 + ( n - 1 )*abs( INCX ) ).
  84. *           Before entry, the incremented array X must contain the n
  85. *           element right-hand side vector b. On exit, X is overwritten
  86. *           with the solution vector x.
  87. *
  88. *  INCX   - INTEGER.
  89. *           On entry, INCX specifies the increment for the elements of
  90. *           X. INCX must not be zero.
  91. *           Unchanged on exit.
  92. *
  93. *
  94. *  Level 2 Blas routine.
  95. *
  96. *  -- Written on 22-October-1986.
  97. *     Jack Dongarra, Argonne National Lab.
  98. *     Jeremy Du Croz, Nag Central Office.
  99. *     Sven Hammarling, Nag Central Office.
  100. *     Richard Hanson, Sandia National Labs.
  101. *
  102. *
  103. *     .. Parameters ..
  104.       COMPLEX*16         ZERO
  105.       PARAMETER        ( ZERO = ( 0.0D+0, 0.0D+0 ) )
  106. *     .. Local Scalars ..
  107.       COMPLEX*16         TEMP
  108.       INTEGER            I, INFO, IX, J, JX, K, KK, KX
  109.       LOGICAL            NOCONJ, NOUNIT
  110. *     .. External Functions ..
  111.       LOGICAL            LSAME
  112.       EXTERNAL           LSAME
  113. *     .. External Subroutines ..
  114.       EXTERNAL           XERBLA
  115. *     .. Intrinsic Functions ..
  116.       INTRINSIC          DCONJG
  117. *     ..
  118. *     .. Executable Statements ..
  119. *
  120. *     Test the input parameters.
  121. *
  122.       INFO = 0
  123.       IF     ( .NOT.LSAME( UPLO , 'U' ).AND.
  124.      $         .NOT.LSAME( UPLO , 'L' )      )THEN
  125.          INFO = 1
  126.       ELSE IF( .NOT.LSAME( TRANS, 'N' ).AND.
  127.      $         .NOT.LSAME( TRANS, 'T' ).AND.
  128.      $         .NOT.LSAME( TRANS, 'C' )      )THEN
  129.          INFO = 2
  130.       ELSE IF( .NOT.LSAME( DIAG , 'U' ).AND.
  131.      $         .NOT.LSAME( DIAG , 'N' )      )THEN
  132.          INFO = 3
  133.       ELSE IF( N.LT.0 )THEN
  134.          INFO = 4
  135.       ELSE IF( INCX.EQ.0 )THEN
  136.          INFO = 7
  137.       END IF
  138.       IF( INFO.NE.0 )THEN
  139.          CALL XERBLA( 'ZTPSV ', INFO )
  140.          RETURN
  141.       END IF
  142. *
  143. *     Quick return if possible.
  144. *
  145.       IF( N.EQ.0 )
  146.      $   RETURN
  147. *
  148.       NOCONJ = LSAME( TRANS, 'T' )
  149.       NOUNIT = LSAME( DIAG , 'N' )
  150. *
  151. *     Set up the start point in X if the increment is not unity. This
  152. *     will be  ( N - 1 )*INCX  too small for descending loops.
  153. *
  154.       IF( INCX.LE.0 )THEN
  155.          KX = 1 - ( N - 1 )*INCX
  156.       ELSE IF( INCX.NE.1 )THEN
  157.          KX = 1
  158.       END IF
  159. *
  160. *     Start the operations. In this version the elements of AP are
  161. *     accessed sequentially with one pass through AP.
  162. *
  163.       IF( LSAME( TRANS, 'N' ) )THEN
  164. *
  165. *        Form  x := inv( A )*x.
  166. *
  167.          IF( LSAME( UPLO, 'U' ) )THEN
  168.             KK = ( N*( N + 1 ) )/2
  169.             IF( INCX.EQ.1 )THEN
  170.                DO 20, J = N, 1, -1
  171.                   IF( X( J ).NE.ZERO )THEN
  172.                      IF( NOUNIT )
  173.      $                  X( J ) = X( J )/AP( KK )
  174.                      TEMP = X( J )
  175.                      K    = KK     - 1
  176.                      DO 10, I = J - 1, 1, -1
  177.                         X( I ) = X( I ) - TEMP*AP( K )
  178.                         K      = K      - 1
  179.    10                CONTINUE
  180.                   END IF
  181.                   KK = KK - J
  182.    20          CONTINUE
  183.             ELSE
  184.                JX = KX + ( N - 1 )*INCX
  185.                DO 40, J = N, 1, -1
  186.                   IF( X( JX ).NE.ZERO )THEN
  187.                      IF( NOUNIT )
  188.      $                  X( JX ) = X( JX )/AP( KK )
  189.                      TEMP = X( JX )
  190.                      IX   = JX
  191.                      DO 30, K = KK - 1, KK - J + 1, -1
  192.                         IX      = IX      - INCX
  193.                         X( IX ) = X( IX ) - TEMP*AP( K )
  194.    30                CONTINUE
  195.                   END IF
  196.                   JX = JX - INCX
  197.                   KK = KK - J
  198.    40          CONTINUE
  199.             END IF
  200.          ELSE
  201.             KK = 1
  202.             IF( INCX.EQ.1 )THEN
  203.                DO 60, J = 1, N
  204.                   IF( X( J ).NE.ZERO )THEN
  205.                      IF( NOUNIT )
  206.      $                  X( J ) = X( J )/AP( KK )
  207.                      TEMP = X( J )
  208.                      K    = KK     + 1
  209.                      DO 50, I = J + 1, N
  210.                         X( I ) = X( I ) - TEMP*AP( K )
  211.                         K      = K      + 1
  212.    50                CONTINUE
  213.                   END IF
  214.                   KK = KK + ( N - J + 1 )
  215.    60          CONTINUE
  216.             ELSE
  217.                JX = KX
  218.                DO 80, J = 1, N
  219.                   IF( X( JX ).NE.ZERO )THEN
  220.                      IF( NOUNIT )
  221.      $                  X( JX ) = X( JX )/AP( KK )
  222.                      TEMP = X( JX )
  223.                      IX   = JX
  224.                      DO 70, K = KK + 1, KK + N - J
  225.                         IX      = IX      + INCX
  226.                         X( IX ) = X( IX ) - TEMP*AP( K )
  227.    70                CONTINUE
  228.                   END IF
  229.                   JX = JX + INCX
  230.                   KK = KK + ( N - J + 1 )
  231.    80          CONTINUE
  232.             END IF
  233.          END IF
  234.       ELSE
  235. *
  236. *        Form  x := inv( A' )*x  or  x := inv( conjg( A' ) )*x.
  237. *
  238.          IF( LSAME( UPLO, 'U' ) )THEN
  239.             KK = 1
  240.             IF( INCX.EQ.1 )THEN
  241.                DO 110, J = 1, N
  242.                   TEMP = X( J )
  243.                   K    = KK
  244.                   IF( NOCONJ )THEN
  245.                      DO 90, I = 1, J - 1
  246.                         TEMP = TEMP - AP( K )*X( I )
  247.                         K    = K    + 1
  248.    90                CONTINUE
  249.                      IF( NOUNIT )
  250.      $                  TEMP = TEMP/AP( KK + J - 1 )
  251.                   ELSE
  252.                      DO 100, I = 1, J - 1
  253.                         TEMP = TEMP - DCONJG( AP( K ) )*X( I )
  254.                         K    = K    + 1
  255.   100                CONTINUE
  256.                      IF( NOUNIT )
  257.      $                  TEMP = TEMP/DCONJG( AP( KK + J - 1 ) )
  258.                   END IF
  259.                   X( J ) = TEMP
  260.                   KK     = KK   + J
  261.   110          CONTINUE
  262.             ELSE
  263.                JX = KX
  264.                DO 140, J = 1, N
  265.                   TEMP = X( JX )
  266.                   IX   = KX
  267.                   IF( NOCONJ )THEN
  268.                      DO 120, K = KK, KK + J - 2
  269.                         TEMP = TEMP - AP( K )*X( IX )
  270.                         IX   = IX   + INCX
  271.   120                CONTINUE
  272.                      IF( NOUNIT )
  273.      $                  TEMP = TEMP/AP( KK + J - 1 )
  274.                   ELSE
  275.                      DO 130, K = KK, KK + J - 2
  276.                         TEMP = TEMP - DCONJG( AP( K ) )*X( IX )
  277.                         IX   = IX   + INCX
  278.   130                CONTINUE
  279.                      IF( NOUNIT )
  280.      $                  TEMP = TEMP/DCONJG( AP( KK + J - 1 ) )
  281.                   END IF
  282.                   X( JX ) = TEMP
  283.                   JX      = JX   + INCX
  284.                   KK      = KK   + J
  285.   140          CONTINUE
  286.             END IF
  287.          ELSE
  288.             KK = ( N*( N + 1 ) )/2
  289.             IF( INCX.EQ.1 )THEN
  290.                DO 170, J = N, 1, -1
  291.                   TEMP = X( J )
  292.                   K    = KK
  293.                   IF( NOCONJ )THEN
  294.                      DO 150, I = N, J + 1, -1
  295.                         TEMP = TEMP - AP( K )*X( I )
  296.                         K    = K    - 1
  297.   150                CONTINUE
  298.                      IF( NOUNIT )
  299.      $                  TEMP = TEMP/AP( KK - N + J )
  300.                   ELSE
  301.                      DO 160, I = N, J + 1, -1
  302.                         TEMP = TEMP - DCONJG( AP( K ) )*X( I )
  303.                         K    = K    - 1
  304.   160                CONTINUE
  305.                      IF( NOUNIT )
  306.      $                  TEMP = TEMP/DCONJG( AP( KK - N + J ) )
  307.                   END IF
  308.                   X( J ) = TEMP
  309.                   KK     = KK   - ( N - J + 1 )
  310.   170          CONTINUE
  311.             ELSE
  312.                KX = KX + ( N - 1 )*INCX
  313.                JX = KX
  314.                DO 200, J = N, 1, -1
  315.                   TEMP = X( JX )
  316.                   IX   = KX
  317.                   IF( NOCONJ )THEN
  318.                      DO 180, K = KK, KK - ( N - ( J + 1 ) ), -1
  319.                         TEMP = TEMP - AP( K )*X( IX )
  320.                         IX   = IX   - INCX
  321.   180                CONTINUE
  322.                      IF( NOUNIT )
  323.      $                  TEMP = TEMP/AP( KK - N + J )
  324.                   ELSE
  325.                      DO 190, K = KK, KK - ( N - ( J + 1 ) ), -1
  326.                         TEMP = TEMP - DCONJG( AP( K ) )*X( IX )
  327.                         IX   = IX   - INCX
  328.   190                CONTINUE
  329.                      IF( NOUNIT )
  330.      $                  TEMP = TEMP/DCONJG( AP( KK - N + J ) )
  331.                   END IF
  332.                   X( JX ) = TEMP
  333.                   JX      = JX   - INCX
  334.                   KK      = KK   - ( N - J + 1 )
  335.   200          CONTINUE
  336.             END IF
  337.          END IF
  338.       END IF
  339. *
  340.       RETURN
  341. *
  342. *     End of ZTPSV .
  343. *
  344.       END
  345.